Ajuda a proteger a Grande Barreira de Corais com TensorFlow em Kaggle Junte Desafio

Reduza o tamanho do binário TensorFlow Lite

Visão geral

Ao implementar modelos para aplicativos de aprendizado de máquina no dispositivo (ODML), é importante estar ciente da memória limitada que está disponível em dispositivos móveis. Os tamanhos binários do modelo estão intimamente relacionados ao número de operações usadas no modelo. O TensorFlow Lite permite reduzir os tamanhos binários do modelo usando compilações seletivas. As compilações seletivas ignoram as operações não utilizadas em seu conjunto de modelos e produzem uma biblioteca compacta apenas com o tempo de execução e os kernels operacionais necessários para que o modelo seja executado em seu dispositivo móvel.

A construção seletiva se aplica às três bibliotecas de operações a seguir.

  1. Biblioteca de operações integrada do TensorFlow Lite
  2. Operações personalizadas do TensorFlow Lite
  3. Selecione a biblioteca de operações do TensorFlow

A tabela abaixo demonstra o impacto das compilações seletivas para alguns casos de uso comuns:

Nome do Modelo Domínio Arquitetura alvo Tamanho (s) do arquivo AAR
Mobilenet_1.0_224 (flutuante) Classificação de imagem armeabi-v7a tensorflow-lite.aar (296.635 bytes)
arm64-v8a tensorflow-lite.aar (382.892 bytes)
ESPECIARIA Extração de tom de som armeabi-v7a tensorflow-lite.aar (375.813 bytes)
tensorflow-lite-select-tf-ops.aar (1.676.380 bytes)
arm64-v8a tensorflow-lite.aar (421.826 bytes)
tensorflow-lite-select-tf-ops.aar (2.298.630 bytes)
i3d-cinética-400 Classificação de vídeo armeabi-v7a tensorflow-lite.aar (240.085 bytes)
tensorflow-lite-select-tf-ops.aar (1.708.597 bytes)
arm64-v8a tensorflow-lite.aar (273.713 bytes)
tensorflow-lite-select-tf-ops.aar (2.339.697 bytes)

Problemas / limitações conhecidos

  1. Compilação seletiva para API C e versão iOS não são suportadas atualmente.

Crie seletivamente o TensorFlow Lite com o Bazel

Esta seção pressupõe que você tenha baixado códigos fonte TensorFlow e configurar o ambiente de desenvolvimento local para Bazel.

Crie arquivos AAR para o projeto Android

Você pode criar os AARs personalizados do TensorFlow Lite fornecendo os caminhos do arquivo de modelo da seguinte maneira.

sh tensorflow/lite/tools/build_aar.sh \
  --input_models=/a/b/model_one.tflite,/c/d/model_two.tflite \
  --target_archs=x86,x86_64,arm64-v8a,armeabi-v7a

O comando acima irá gerar o arquivo AAR bazel-bin/tmp/tensorflow-lite.aar para TensorFlow Lite embutido e personalizado ops; e, opcionalmente, gera o arquivo aar bazel-bin/tmp/tensorflow-lite-select-tf-ops.aar se os seus modelos contêm ops Select TensorFlow. Observe que isso cria um AAR "gordo" com várias arquiteturas diferentes; se você não precisar de todos eles, use o subconjunto apropriado para seu ambiente de implementação.

Construir com operações personalizadas

Se você desenvolveu modelos do Tensorflow Lite com operações personalizadas, pode criá-los adicionando as seguintes sinalizações ao comando de compilação:

sh tensorflow/lite/tools/build_aar.sh \
  --input_models=/a/b/model_one.tflite,/c/d/model_two.tflite \
  --target_archs=x86,x86_64,arm64-v8a,armeabi-v7a \
  --tflite_custom_ops_srcs=/e/f/file1.cc,/g/h/file2.h \
  --tflite_custom_ops_deps=dep1,dep2

O tflite_custom_ops_srcs bandeira contém arquivos de origem de seus ops personalizados eo tflite_custom_ops_deps bandeira contém dependências para construir os arquivos de origem. Observe que essas dependências devem existir no repositório TensorFlow.

Usos avançados: regras personalizadas do Bazel

Se o seu projeto está usando o Bazel e você gostaria de definir dependências TFLite personalizadas para um determinado conjunto de modelos, você pode definir as seguintes regras no repositório do projeto:

Apenas para os modelos com operações integradas:

load(
    "@org_tensorflow//tensorflow/lite:build_def.bzl",
    "tflite_custom_android_library",
    "tflite_custom_c_library",
    "tflite_custom_cc_library",
)

# A selectively built TFLite Android library.
tflite_custom_android_library(
    name = "selectively_built_android_lib",
    models = [
        ":model_one.tflite",
        ":model_two.tflite",
    ],
)

# A selectively built TFLite C library.
tflite_custom_c_library(
    name = "selectively_built_c_lib",
    models = [
        ":model_one.tflite",
        ":model_two.tflite",
    ],
)

# A selectively built TFLite C++ library.
tflite_custom_cc_library(
    name = "selectively_built_cc_lib",
    models = [
        ":model_one.tflite",
        ":model_two.tflite",
    ],
)

Para os modelos com as ops Select TF :

load(
    "@org_tensorflow//tensorflow/lite/delegates/flex:build_def.bzl",
    "tflite_flex_android_library",
    "tflite_flex_cc_library",
)

# A Select TF ops enabled selectively built TFLite Android library.
tflite_flex_android_library(
    name = "selective_built_tflite_flex_android_lib",
    models = [
        ":model_one.tflite",
        ":model_two.tflite",
    ],
)

# A Select TF ops enabled selectively built TFLite C++ library.
tflite_flex_cc_library(
    name = "selective_built_tflite_flex_cc_lib",
    models = [
        ":model_one.tflite",
        ":model_two.tflite",
    ],
)

Usos avançados: construir bibliotecas compartilhadas C / C ++ personalizadas

Se você gostaria de construir seus próprios objetos compartilhados TFLite C / C ++ personalizados para os modelos fornecidos, você pode seguir as etapas abaixo:

Crie um arquivo BUILD temporário executando o seguinte comando no diretório raiz do código-fonte do TensorFlow:

mkdir -p tmp && touch tmp/BUILD

Construindo objetos compartilhados C personalizados

Se você gostaria de construir um costume TFLite C objeto compartilhado, adicione o seguinte ao tmp/BUILD arquivo:

load(
    "//tensorflow/lite:build_def.bzl",
    "tflite_custom_c_library",
    "tflite_cc_shared_object",
)

tflite_custom_c_library(
    name = "selectively_built_c_lib",
    models = [
        ":model_one.tflite",
        ":model_two.tflite",
    ],
)

# Generates a platform-specific shared library containing the TensorFlow Lite C
# API implementation as define in `c_api.h`. The exact output library name
# is platform dependent:
#   - Linux/Android: `libtensorflowlite_c.so`
#   - Mac: `libtensorflowlite_c.dylib`
#   - Windows: `tensorflowlite_c.dll`
tflite_cc_shared_object(
    name = "tensorflowlite_c",
    linkopts = select({
        "//tensorflow:ios": [
            "-Wl,-exported_symbols_list,$(location //tensorflow/lite/c:exported_symbols.lds)",
        ],
        "//tensorflow:macos": [
            "-Wl,-exported_symbols_list,$(location //tensorflow/lite/c:exported_symbols.lds)",
        ],
        "//tensorflow:windows": [],
        "//conditions:default": [
            "-z defs",
            "-Wl,--version-script,$(location //tensorflow/lite/c:version_script.lds)",
        ],
    }),
    per_os_targets = True,
    deps = [
        ":selectively_built_c_lib",
        "//tensorflow/lite/c:exported_symbols.lds",
        "//tensorflow/lite/c:version_script.lds",
    ],
)

O alvo recém-adicionado pode ser construído da seguinte maneira:

bazel build -c opt --cxxopt=--std=c++14 \
  //tmp:tensorflowlite_c

e para Android (substitua android_arm com android_arm64 para 64-bit):

bazel build -c opt --cxxopt=--std=c++14 --config=android_arm \
  //tmp:tensorflowlite_c

Criação de objetos compartilhados C ++ personalizados

Se você gostaria de construir um costume TFLite C ++ objeto compartilhado, adicione o seguinte ao tmp/BUILD arquivo:

load(
    "//tensorflow/lite:build_def.bzl",
    "tflite_custom_cc_library",
    "tflite_cc_shared_object",
)

tflite_custom_cc_library(
    name = "selectively_built_cc_lib",
    models = [
        ":model_one.tflite",
        ":model_two.tflite",
    ],
)

# Shared lib target for convenience, pulls in the core runtime and builtin ops.
# Note: This target is not yet finalized, and the exact set of exported (C/C++)
# APIs is subject to change. The output library name is platform dependent:
#   - Linux/Android: `libtensorflowlite.so`
#   - Mac: `libtensorflowlite.dylib`
#   - Windows: `tensorflowlite.dll`
tflite_cc_shared_object(
    name = "tensorflowlite",
    # Until we have more granular symbol export for the C++ API on Windows,
    # export all symbols.
    features = ["windows_export_all_symbols"],
    linkopts = select({
        "//tensorflow:macos": [
            "-Wl,-exported_symbols_list,$(location //tensorflow/lite:tflite_exported_symbols.lds)",
        ],
        "//tensorflow:windows": [],
        "//conditions:default": [
            "-Wl,-z,defs",
            "-Wl,--version-script,$(location //tensorflow/lite:tflite_version_script.lds)",
        ],
    }),
    per_os_targets = True,
    deps = [
        ":selectively_built_cc_lib",
        "//tensorflow/lite:tflite_exported_symbols.lds",
        "//tensorflow/lite:tflite_version_script.lds",
    ],
)

O alvo recém-adicionado pode ser construído da seguinte maneira:

bazel build -c opt  --cxxopt=--std=c++14 \
  //tmp:tensorflowlite

e para Android (substitua android_arm com android_arm64 para 64-bit):

bazel build -c opt --cxxopt=--std=c++14 --config=android_arm \
  //tmp:tensorflowlite

Para os modelos com as operações Select TF, você também precisa construir a seguinte biblioteca compartilhada:

load(
    "@org_tensorflow//tensorflow/lite/delegates/flex:build_def.bzl",
    "tflite_flex_shared_library"
)

# Shared lib target for convenience, pulls in the standard set of TensorFlow
# ops and kernels. The output library name is platform dependent:
#   - Linux/Android: `libtensorflowlite_flex.so`
#   - Mac: `libtensorflowlite_flex.dylib`
#   - Windows: `libtensorflowlite_flex.dll`
tflite_flex_shared_library(
  name = "tensorflowlite_flex",
  models = [
      ":model_one.tflite",
      ":model_two.tflite",
  ],
)

O alvo recém-adicionado pode ser construído da seguinte maneira:

bazel build -c opt --cxxopt='--std=c++14' \
      --config=monolithic \
      --host_crosstool_top=@bazel_tools//tools/cpp:toolchain \
      //tmp:tensorflowlite_flex

e para Android (substitua android_arm com android_arm64 para 64-bit):

bazel build -c opt --cxxopt='--std=c++14' \
      --config=android_arm \
      --config=monolithic \
      --host_crosstool_top=@bazel_tools//tools/cpp:toolchain \
      //tmp:tensorflowlite_flex

Crie seletivamente o TensorFlow Lite com Docker

Esta seção assume que você tenha instalado Docker em sua máquina local e baixou o TensorFlow Lite Dockerfile aqui .

Depois de baixar o Dockerfile acima, você pode construir a imagem do docker executando:

docker build . -t tflite-builder -f tflite-android.Dockerfile

Crie arquivos AAR para o projeto Android

Baixe o script para construir com o Docker executando:

curl -o build_aar_with_docker.sh \
  https://raw.githubusercontent.com/tensorflow/tensorflow/master/tensorflow/lite/tools/build_aar_with_docker.sh &&
chmod +x build_aar_with_docker.sh

Em seguida, você pode criar o TensorFlow Lite AAR personalizado, fornecendo os caminhos do arquivo de modelo da seguinte maneira.

sh build_aar_with_docker.sh \
  --input_models=/a/b/model_one.tflite,/c/d/model_two.tflite \
  --target_archs=x86,x86_64,arm64-v8a,armeabi-v7a \
  --checkpoint=master \
  [--cache_dir=<path to cache directory>]

O checkpoint bandeira é um commit, uma sucursal ou um tag do repo TensorFlow que deseja check-out antes de construir as bibliotecas; por padrão, é o branch de lançamento mais recente. O comando acima irá gerar o arquivo AAR tensorflow-lite.aar para TensorFlow Lite embutido e ops personalizados e, opcionalmente, o arquivo AAR tensorflow-lite-select-tf-ops.aar para ops Select TensorFlow no seu diretório atual.

O --cache_dir especifica o diretório de cache. Se não for fornecido, o script irá criar um diretório chamado bazel-build-cache sob o diretório de trabalho atual para o cache.

Adicionar arquivos AAR ao projeto

Adicionar arquivos AAR pela diretamente importar o AAR em seu projeto , ou pela publicação da AAR personalizado para seu repositório local Maven . Note que você tem que adicionar os arquivos AAR para tensorflow-lite-select-tf-ops.aar bem se você gerá-lo.